Excel——讓排課更省心
易禮雲
Excel——讓排課更省心
I
前言
課程編制是教務處每學期一項令人頭疼的工作，複雜而繁瑣，
時間緊任務重。其中必須要解決的問題是課程衝突，否則教學工
作無法正常開展。最難解決的問題是課程編排的合理性，因為對
不同學校，不同的教師，對"合理"的定義是不一樣的，一個理
想的課程表應該是能滿足學校、教師的大部分"合理"要求。排
課時要考慮如下因素：教學資源情況，如有幾個微機室？幾個音
樂室？一節課同時能容納幾個班上體育課？；學科分佈及均衡性，
畢竟還是要講究科學性的。
以前老師們用原始的方法手工編排：一般是先在電腦上製作
並打印出一張總課表的空表，再打印一張教師工作安排表用來對
照，然後在空白課表上寫寫畫畫，期間，還要不斷的調整，一支
鉛筆塗來擦去。這還不算完，在排好總課表後,還要從總課表中提
取班級課表和教師個人課表,工作量大不說,而且容易出錯。排課
的同時還要在旁邊統計課程數據，如 1 班的語文排了幾節？還差
幾節？3 班的數學排了„„，伏案數小時才可收工，費時費力；
現在雖有專業的排課軟件，但用軟件排課基本不能令人滿意：普
遍存在排課條件設置複雜，難以操作等缺點，最重要的是排出的
課合理性差。
若您沒有排課軟件，又不想回到從前，那麼 excel 便是您最
佳的選擇。excel 的強大威力來自於它的公式，條件格式和數據有
效性。本人在這方面作了一些嘗試，設計了一個簡單實用的排課
Excel——讓排課更省心
II
模板，用人的思維（手工排課）加上電腦的"監控"（教師、教
室衝突檢查），使排課變得更簡單、省心，工作量降低不說，效
率大為提高。排好課後，教師個人課表、班級課表就自動生成了，
直接打印出來就可分發給老師和班主任，如果課程還有變動，教
師個人課表和班級課表也會自動跟蹤，充分顯示出 Excel 的智能
性，現寫出來供大家參考。
簡要說明：我用的 Excel 版本是 2010 版，讀者要看懂這本小
冊子，需要具備一些 Excel 的基本知識，並應當瞭解 Excel 的公式
與函數基礎才能跟上我的節奏。為了讓讀者真正從中受益，我會
在後面的文字中，凡用到公式的地方都會有一些簡短的說明，當
然也包括一些 Excel 技巧。就是說，當您看完這本小冊子的時候，
不僅僅是在排課方面有收穫，我更希望您的 Excel 水平有提高，
這才是我寫這些文字的初衷。所有的截圖都是用 QQ 聊天軟件的
截圖功能製作。
我們學校是一所全日制縣級初中，原來三個年級分別都有 16
個教學班，雖然現在班級減少了，但我的這個課表仍然沒有刪除
多出來的班級，如果覺得礙眼，可以將多餘的班級隱藏，並不影
響表格的運行。當然如果您所在的學校班級與我這個表差別太多，
也可以將多餘的班級刪除，不過，刪除後公式會作一些調整來適
應新表，才能使表格不發生錯誤。目前我校的規模是：七年級 14
個班，八年級 13 個班，九年級 15 個班。按我校的慣例及教育局
規定，每週工作 5 天，每天上、下午各 4 節課，但週五的下午只
有 2 節，全周共 38 節課，每週一上午的第一節課全校均為班會
課，本模板的設計不包含早讀課及晚自習。
Excel——讓排課更省心
III
目錄
前言 .............................................................................................. I
目錄 ............................................................................................. 3
第 1 章 工作安排 ................................................................. 1
1.1 概述 ................................................................................ 1
1.2 工作安排 ........................................................................ 2
第 2 章 總課表 ..................................................................... 5
1.1 排課區 ............................................................................ 5
1.2 任課教師區 .................................................................... 6
1.3 統計區 ............................................................................ 8
第 3 章 教師課表 ............................................................... 11
3.1 教師個人課表 .............................................................. 11
3.2 製作多個教師個人課表 .............................................. 15
Excel——讓排課更省心
IV
第 4 章 班課表 ................................................................... 17
第 5 章 年級課表 ............................................................... 21
第 6 章 教師課表數據 ........................................................ 23
1.1 主文檔的製作 ............................................................... 23
1.2 課程名稱 ....................................................................... 24
1.3 任課班級 ....................................................................... 26
1.4 郵件合併 ....................................................................... 27
第 7 章 班課表數據............................................................ 31
1.1 課程名稱 ....................................................................... 31
1.2 任課教師姓名 ............................................................... 32
附 1：截圖目錄 ......................................................................... 35
附 2：公式目錄 ......................................................................... 37
附 3 EXCEL 常用技巧集 .............................................................. 41
1.3 移動及選定單元格 ....................................................... 41
Excel——讓排課更省心
V
1.4 複製和粘貼 .................................................................. 43
1.5 數據錄入 ...................................................................... 44
1.6 數據排序 ...................................................................... 45
1.7 表格打印 ...................................................................... 46
1
第1章 工作安排
1.1 概述
我將整個課表製作成一個工作薄文件（xlsx 文件），它包含的
工作表數目由您的需要來定，我這裡包含 7 個工作表（圖 1-1）。
課表製作好後，刪除工作安排裡的數據（注意只刪除數據，不刪
除格式）及總課表裡的排課數據，另存為一個模板文件（xltx 文
件），以後就可以在它的基礎上導入工作安排，然後再進行人工
排課，其它的就會自動生成，是不是覺得很方便呢？
圖 1-1 工作表列表
首先，新建一個 excel 工作薄，默認有 3 個工作表，再插入 4
個表，共 7 張工作表，分別命名為：安排，總課表，教師課表，
班課表、年級課表、教師課表數據及班課表數據（圖 1-1）。每個
表的製作及作用，後面會分別進行說明。這樣準備工作就算完成
了，下面依順序進行簡要說明。
"安排"表是學校對老師的工作安排，從這個表裡可以看出
哪個老師上哪些班的什麼課，這是製作這個工作薄的基礎，是由
開學前行政會決定的。在它的基礎上，我們來製作全校"總課表"，
這個靠的是教務人員的智慧，表格只能作一些輔助，比如出現課
Excel——讓排課更省心
2
程衝突時用顏色顯示（提醒），課程排得合理與否，這個表是關
鍵。有了"總課表"，其它表就是用 Excel 的函數來抽取總課表中
的信息並按要求製作成您希望的格式，比如教師課表、班課表以
及年級課表（因為我們學校班級較多，所以分年級製作課表；您
可視情況而定）。最右邊兩個表則是為了批量打印而製作的，主
要是利用 Word 的郵件合併功能，在 Word 裡將教師課程表和班
級課程表設計好，利用"郵件合併"功能，提取該工作中的數據，
最後合併成一個完全的 Word 文件，便於批量打印；如果您校的
班級少，這兩個表就不必製作了，直接在該工作薄的"教師課表"
和"班課表"中一張一張地打印即可。下面就先從第一張表說起。
1.2 工作安排
參照圖 1-2 製作表格並輸入您校老師的任課情況。
圖 1-2"安排"表
第 2 行標註顏色是為了區分不同的年級，715、716 是空白（我
第 1 章 工作安排
3
校今年七年級只有 14 個班，多餘的班級編號未刪除），您可以不
用理會，當然也可以將其隱藏。為了能一眼就看出哪些老師是跨
年級上課，哪些老師是跨學科任課，需要在 Excel 的"條件格式"
裡進行設置，具體方法如下：
選中$B$3:$Q$17，在"開始"選項裡，單擊"樣式"組裡的
"條件格式→新建規則"，在彈出來的"新建格式規則"對話框
裡選擇最後一項"使用公式確定要設置格式的單元格"，然後輸
入公式：
=COUNTIF($R$3:$AW$17,B3)
設置好格式後點確定（我設置的單元格格式是"單元格背景
填充，顏色是橙黃色"，您可以根據自己的喜好進行設置）。公式
說明：COUNTIF 函數用於條件計數，第一個參數是條件範圍，第
二個參數是條件。該公式的第一參數$R$3:$AW$17 是八、九年級
的範圍，意思是：在八、九年級範圍內，統計七年級範圍內的任
課教師姓名，如果不為 0，則表示跨年級任課，應用格式，相應
單元格顯示有背景色；如果為 0 則條件不滿足，正常顯示。
用類似的方法設置跨學科的任課老師，方法是：選中
$B$3:$AW$16，在條件格式的公式裡輸入如下公式：
=COUNTIF($B4:$AW$17,B3)
同樣設置好格式後點確定（我設置的單元格格式是"單元格
背景填充，顏色是綠色"，您可以根據自己的喜好進行設置）。公
Excel——讓排課更省心
4
式說明：該公式的第一參數$B4:$AW$17 是除（數據區）第 1 行
（事實上是表格的第 3 行）外的其它所有行，特別要注意是混合
引用，這樣就可以統計出以下各行中是否包含有第 1 行的任課老
師（不同的行，意味著不同的學科，參看第 1 列），如果有，則
表示跨學科任教（跨行就是跨學科），應用條件格式（單元格背
景顯示綠色）；如果統計結果為 0，則表示不符合條件，單元格正
常顯示。這樣，這個表格就算完成了，為了使以後的一些統計（如
績效）更方便，我還在這個表格的其餘部分輸入了一些公式，當
然這個不是必須的。如我在表格的下面 A20 單元格里輸入了一個
統計任課教師數（不重複）的公式
{=SUM(1/COUNTIF(teachers,teachers&""))-1}
這是一個數組公式，公式輸完後要按 Ctrl+Shift+Enter 三個鍵，
其中的花括號是自動生成的，手工輸入無效，teachers 是我為這
個表的數據區定義的名稱，=$B$3:$AW$17。另外還在 BA2 單元格
裡輸入公式
=OFFSET($B$3,INT((ROW()-2)/48),MOD(ROW()-2,48))
將這個公式複製到 BA721 並將其轉化成數值（複製→選擇性
粘貼→數值），然後在"數據"選項裡，單擊"數據工具"裡的
"刪除重複項"工具，留下唯一值，再將 0 值刪除，就得到了任
課教師的不重複列表。按上面的方法，也可以分別列出七、八、
九三個年級的任課教師不重複列表。
5
第2章 總課表
本章介紹"總課表"的編制，表格分成三個區：一是排課區
域（$A$2:$AX$41），其右側是任課教師姓名區域（$AY$3:$CT$41），
而下邊則是統計區（$B$42:$AX$59）。排課區用於安排課程，每
當排了一節課，任課教師區就會顯示該節課的任課教師（用公式
來設定），這兩個區要一一對應，就是說，排課區多大，任課教
師區也是多大，為防止出錯，也在該區域上面寫上對應的班級。
下面的統計區用於統計各班、各學科已經排了幾節課，是否已排
滿，或者是否已超過應當安排的節數，總課時是否已超出等，下
面分別說明。
2.1 排課區
如圖 2-1，橫向為班級，第 1 列為星期，第 2 列為節次，中
間為人工排的課。
圖 2-1 總課表
Excel——讓排課更省心
6
為方便排課，可以應用 Excel 的數據有效性，將排課區的數
據作一些限定，方法如下：
選定整個排課的數據區（$A$3:$AX$41），在"數據"選項裡，
單擊"數據工具"的"數據有效性"，選擇"數據有效性"，在彈
出的"數據有效性"對話框裡，"允許"下選擇"序列"，"來源"
裡輸入"=語文,數學,英語,思品,歷史,地理,生物,物理,化學,體育,音
樂,美術,陽光,信息,英活"①，然後單擊確定完成設置。這樣，當
你在排課的時候就多了一種選擇：既可以直接從鍵盤敲入，又可
以用下拉選單選擇輸入，如下圖所示。
圖 2-2 下拉選單輸入
2.2 任課教師區
緊鄰排課區的右側對應位置，設計任課教師姓名區。設計思
①本欄裡輸入您校實際課程。
第 2 章 總課表
7
路是：當左側排課區的某節課排定後，通過公式在右側顯示出該
堂課的任課老師姓名，這個區域設計的目的是為防止課程衝突作
準備。如 AY3 單元格的公式如下：
=IFERROR(VLOOKUP(C3,arrangement,COLUMN()-49,0),"")
這是一個函數嵌套公式，它由三個函數構成，其中，IFERROR
（函數,""），意思是當括號內的函數值出現錯誤時，顯示為"空"；
不出現錯誤時，顯示函數本身的結果。其作用是避免當函數出現
錯誤時顯示錯符號。第二個函數 VLOOKUP 用於查找，在
arrangement 裡查找 C3（課程名稱）的值（在這裡是"班會"），
找到後，顯示查找區域裡第 column()-49 列的值（在這裡就是班
會課的任課教師姓名）。函數 column()用於顯示活動單元格的列數，
參數為空，column()-49②的值要與 Arrangement 區域的值對應。
Arrangement 是一名稱，它代表安排表裡的數據區，即：=安
排!$A$2:$AW$19。當然你也可以不用名稱，而直接用數據區域來
代入，效果是一樣的，用名稱的目的是簡化公式，讓公式看起來
既具有可讀性，又顯得簡潔。
有了任課教師姓名區，現在回過頭來設計課程衝突顏色顯示。
選中排課區，即$C$3:$AX$41，在條件格式的"公式"裡輸入如
下公式並設置顏色（我這裡設定的是紅色字體）：
② 這裡之所以是減 49，是根據表的結構決定的，如果您的表的行列數
與這裡的表不一樣，就要調整這個數的值來適應您的表。
Excel——讓排課更省心
8
=COUNTIF($AY3:$CT3,AY3)>1
注意單元格的引用是混合引用。
設計思路：一個老師在同一天同一節課，只能上一個班的課，
如果同一天同一節課安排了某個老師超過 1 節課的情況出現，就
將該課程用紅色顯示出來提示排課者，這樣，排課老師馬上就可
以發現問題，以便及時糾正。從"總課表"看出，同一天同一節
課，其實就對應"總課表"的一行，所以上面公式裡第一個參數
用的是行相對引用，第二個參數要用相對引用。該公式的意思是：
在任課教師姓名區$AY3:$CT3 中統計 AY3 單元格中老師是否重複
（結果>1 就是重複），如果是就用顏色顯示，如果否就正常顯示。
2.3 統計區
統計區（$B$42:$AX$59）是用來統計已排節數的區域，如圖
2.3，左側的學科由"安排"表複製而來，上面的班級與本表第 2
行的班級對應。在 C43 單元格輸入公式
=COUNTIF(C$3:C$41,$B43)
這個公式統計 701 班（七年級 1 班）全周"語文"課（$B43
單元格的值）的已排節數，注意是混合引用。將該公式複製到
C43:AX58，統計區的設計就算完成。當然您還可以進一步優化這
個表，比如，用條件格式將不等於規定節數的單元格用顏色顯示
出來，這裡就不多說了。
第 2 章 總課表
9
圖 2-3 統計區部分截圖
至此，整個"總課表"的編輯就結束了。
11
第3章 教師課表
3.1 教師個人課表
當"總課表"設計完成，並且課程已排好，那麼本章介紹的
"教師課表"便是將"總課表"的數據抽取出來，按照個人喜歡
的形式製作成單個課程表，如圖圖 3-1。
圖 3-1 教師個人課表
Excel——讓排課更省心
12
這個表共有 11 行，7 列，其中，第 1 行為標題，第 2 行為教
師姓名及日期，第 3 至第 11 行為課程表主體，每節課既顯示課
程名稱，也顯示班級名稱。在 B4 單元格里輸入公式：
=IFERROR(INDEX(總課表!$C3:$AX3,MATCH($B$2,總課
表!$AY3:$CT3,0))&CHAR(10)&HLOOKUP($B$2,總課
表!$AY3:$CT$42,44-ROW(),0),"")
公式說明：第一個函數 IFERROR(函數,"")，前面已經說過，用
來將函數出錯時，不顯示錯誤而顯示空白；公式其餘部分被分成
兩個部分，以 CHAR(10)①為分界點，前面部分用來顯示課程名稱，
後面部分用來顯示班級名稱。第二個函數 INDEX（範圍②,列數）
用來搜索出由第 2 參數"列數"確定的課程名稱。第三函數
MATCH($B$2③,總課表!$AY3:$CT3④,0)用來匹配$B$2 單元格里的那
個教師，在"總課表"任課教師區的第 1 行裡排在第幾列？這個
值也就是前面 INDEX（範圍,列數）函數的第 2 個參數。
① 該函數為一回車符，需要將該單元格格式設置為"自動換行"。
②範圍：總課表!$C3:$AX3，即"總課表"排課區的第 1 行，也就是星期
一的第一節課，正好與"教師課表"星期一的第一節課對應。
③ 為教師姓名單元格，為絕對引用。
④總課表!$AY3:$CT3 為"總課表"的任課教師姓名區的第 1 行，與排課
區的第 1 行對應。
第 3 章 教師課表
13
再來看第二部分是如何顯示出班級名稱來的。
函數 HLOOKUP($B$2,範圍⑤,行數,0)，用來在"總課表"的任
課教師區查找該教師（$B$2 單元格確定的教師），並由第 3 參數
"行數⑥"來確定最終顯示的值，這個值就是"總課表"第 42 行
顯示的班級數值。第 4 個參數 0，說明是精確查找，否則為模糊
查找。
現將 B4 單元格里的公式複製到 B11，那麼星期一的課程表就
製作好了；依據同樣的原理製作其他星期的課程，現在列出星期
二第 1 節課（C4 單元格）的公式：
=IFERROR(INDEX(總課表!$C11:$AX11,MATCH($B$2,總課
表!$AY11:$CT11,0))&CHAR(10)&HLOOKUP($B$2,總課
表!$AY11:$CT$42,36-ROW(),0),"")
看起來好像還是那麼複雜，其實只要第 1 個公式琢磨透了，
這個公式就是一樣的了，也不必重新輸入，那該怎樣操作呢？方
法是：將 B11 單元格里的公式複製到 B12，選中 B12 單元格，將
公式編輯欄裡的內容複製並粘貼到 C4 單元格並稍作修改⑦即成。
⑤ 此處的範圍指：總課表!$AY3:$CT$42，對照 Excel 的課程表來看，此
範圍其實就是"總課表"任課教師區。
⑥ 此"行數"為：44-ROW()，看得出，越往下，該值遞減。
⑦ 修改的部分僅限於該公式的最後部分，將原來的 44-row()，修改為
Excel——讓排課更省心
14
同樣的道理可列出星期三第 1 節課（D4 單元格）的公式：
=IFERROR(INDEX(總課表!$C19:$AX19,MATCH($B$2,總課
表!$AY19:$CT19,0))&CHAR(10)&HLOOKUP($B$2,總課
表!$AY19:$CT$42,28-ROW(),0),"")
需修改的部分參照上面。星期四第 1 節課（E4 單元格）的公
式：
=IFERROR(INDEX(總課表!$C27:$AX27,MATCH($B$2,總課
表!$AY27:$CT27,0))&CHAR(10)&HLOOKUP($B$2,總課
表!$AY27:$CT$42,20-ROW(),0),"")
星期五第 1 節課（F4 單元格）的公式：
=IFERROR(INDEX(總課表!$C35:$AX35,MATCH($B$2,總課
表!$AY35:$CT35,0))&CHAR(10)&HLOOKUP($B$2,總課
表!$AY35:$CT$42,12-ROW(),0),"")
由此看出，只要搞清楚了原理，這個表的製作也不是太難，
關鍵是第 1 個公式，其它的只需複製並稍作修改即可。
這樣，這個表就算完成了，最後就是進行頁面設置，使它能
36-row()，就可以了，是不是很簡單呢？
第 3 章 教師課表
15
夠在一張 A4 紙（當然也可以是 B5 紙）上完全顯示。有了這個表，
只要在$B$2 單元格里輸入教師姓名，那麼他的全周課程就全部顯
示出來，直接打印出來發給該教師就行了，缺點是打印完一位老
師，就要在$B$2 單元格里重新輸入另一個老師的姓名，才能打印
第二位老師的課程表。如果您校教師人數不多，這樣也不是太麻
煩；如果像我們學校一樣，有一百多老師，那效率就太低了，我
們暫且將這個問題擱置，後面有辦法解決它。
3.2 製作多個教師個人課表
為了調課的方便，以這個表為基礎，再製作兩個一樣的表，
但由於位置變了，所以公式也需要作一些改變，不過，有了第一
個表作基礎，這兩個表中的公式可以如法炮製出來。具體方法是：
先複製第一個表，將它粘貼到右側適當位置，然後將公式中的
$B$2 替換成$J$2⑧就可以了，還有一點不同的是，為了方便調課，
在該表中設計了一個電話號碼，以便需要調課的老師協商，也就
是在$L$2 單元格輸入瞭如下公式：
=IFERROR(VLOOKUP($J$2,電話,2,0),"")
公式中的"電話"為一名稱，其實就是"電話列表"區域，
如果沒有查找到該教師的電話，則顯示為"空"，避免出現錯誤
⑧ $J$2 為該表教師姓名所在的單元格。
Excel——讓排課更省心
16
符號。這個公式雖然簡單，但用處很大，還希望您能夠逐漸熟悉
它。
用同樣的方法再製作出一個"教師個人課表"來，然後還需
要製作出一個班級課表並放在適當地方，這個表的製作方法稍後
說明。其實只要有第一個表就行了，後面的三個表都不是必須，
嫌麻煩的話，可以不做，一個表足夠了。
17
第4章 班課表
這張表是要打印出來貼在班上的，同樣是從"總課表"中通
過公式將數據抽取出來，填在您製作好的班級課程表中，它大致
應該長成圖 4-1 的樣子
圖 4-1 班級課表
先將頁面按 A4 或 B5 紙張設置好（因為最後是要打印出來的），
Excel——讓排課更省心
18
然後將表格的骨架做出來，最後來寫公式。
這個表的班級選擇在$H$1，可以手工直接在該單元格中輸入
班級，如果不喜歡這樣，那就設置條件格式，然後用鼠標來選擇。
具體方法是：先將"安排"表中的$B$2:$AW$2 區域定義為名稱
（我這裡叫），然後在數據有效性設置的"允許"下選"序列"，
在"來源"後填入：=classes。
$B$2 單元格用來顯示班級名稱，公式如下：
=HLOOKUP($H$1,安排!A2:$AW$19,18,0)
這個公式前面遇到過，就不多解釋了。
$C$2 單元格顯示該班班主任姓名，公式如下：
=HLOOKUP($H$1,arrangement,17,0)
這個公式與$B$2 單元格里的公式基本相同，只是這裡不是單
元格引用，而是用了名稱，arrangement=安排!$A$2:$AW$19，其
它就沒什麼了。
下面來看星期一第 1 節課（單元格 B4）的公式：
=HLOOKUP($H$1,排課,ROW()-2+8*(COLUMN()-2),0)&CHAR(10)
&CHAR(10)&HLOOKUP($H$1,任課教師,
ROW()-2+8*(COLUMN()-2),0)
第 4 章 班課表
19
這公式看起來比較長，也比較複雜一點，粗一看可能會把您
嚇跑，但仔細研究一下也沒出現新函數，都是之前見過的，由於
公式嵌套會使得您望而生畏。如果搞清楚公式中的每個函數以及
它的參數特點，就不難理解了。下面作一些說明：
先說兩個名稱，一是：排課=總課表!$C$2:$AX$42，其實就是
"總課表"的排課區；二是：任課教師=總課表!$AY$2:$CT$40，
它是"總課表"的任課教師區。整個公式由兩部分構成，以
CHAR(10)①函數為分界點，第一部分顯示課程名稱，由
HLOOKUP($H$1,排課,ROW()-2+8*(COLUMN()-2),0)決定；第二部分
顯示該課程任課教師，由 HLOOKUP($H$1,任課教師,
ROW()-2+8*(COLUMN()-2),0)決定。如果像這樣將這個長公式分解
為兩部分，是不是就將公式變短了呢？
第一部分思路是，用 HLOOKUP 函數，在"排課"區域去查
找班級名稱（$H$1 單元格所代表的值），找到後，返回該區域的
第 ROW()②-2+8*(COLUMN()③-2)④行對應值，這便是該節課的課程
① CHAR(10)函數其實是一個換行符，用兩個這樣的函數，是為了讓行間
距大一些，用一個也可以。
② 返回該單元格（B4）的行數。
③ 返回該單元格（B4）的列數。
④ 整個 ROW()-2+8*(COLUMN()-2 的值是湊出來的。當然，規律也是有的。
比如 8*(COLUMN()-2，為什麼是這個樣子的呢？去看看"總課表"的排課區
就知道了，原來每隔 8 行（即 8 節課）就是一個輪迴，因此，當星期二的第
Excel——讓排課更省心
20
名稱了。
第二部分跟第一部分是完全類似的，自己試著去理解一下吧。
中間用兩個 CHAR(10)函數連接起來，構成兩行，同時兩行還有間
隔，這樣看起來是不是要美觀點呢。有了這個公式後，只需要將
複製到全表就行了，複製後不作任何修改，這個表就基本完成了。
為了讓班級課表更完善，我繪製了三個較寬的矩形，並分別
輸入文字，用來提示"課間操"、"午餐"和"眼保健操"，適當
調整三個矩形框的尺寸，使可使得矩形框與整個課表比較協調。
由於矩形框要佔據一定的位置，所以它所佔據的那一行的高度要
調整得高些，作一些格式上的修飾，使表看起來更協調就可以了。
可能有人會問，為什麼要用矩形框而不讓它單獨佔一行？也
不是不可以，我之前就是這麼做的，但是，帶來的據點是：它下
面一行的公式要作修正，個人覺得麻煩，於是就上了這樣的手段，
好處很明顯：只需一個公式，然後複製就完成，完全不需調整。
懂得這個表的製作原理，那麼先前在"教師課表"那一章裡
留下的懸念，自然也就明白了。
1 節課來臨時，就已經過去 8 行了。
21
第5章 年級課表
我校班級較多，所謂"總課表"其實是分年級打印的，所以
才有這樣的名稱。如果學校規模不大，也可以將三個年級的課表
製作在一張 A4 紙上，從而設計出真正的總課表來。
年級課表分年級製作成三個表，如果打印的話，就是三頁，
每個年級一佔頁，三個表的結構完全一樣，但公式是有區別的，
因為每個表所處的行的位置不一樣，但都可以用同樣的原理去理
解，一旦理解了，再來分析公式就不難了。現在，先將年級課表
的樣子做出來，然後寫出第一個公式，也就是 B4 單元格（七年
級 1 班星期一第 1 節課）裡的公式：
=HLOOKUP(C$3,排課,ROW()-2+8*INT((COLUMN()-3)/16),0)
如果表格橫向放得下的話（我這裡放不下，將星期四和星期
五兩天的課折行顯示），直接將這個公式複製到整個年級就完成
了，但是，由於星期四和星期五的課表提到了下面去顯示，使得
公式到這裡後要作一些調整。調整後 C14 單元格（星期四第 1 節
課）裡的公式就變成如下的形式：
=HLOOKUP(C$3,排課,ROW()+12+8*INT((COLUMN()-3)/16),0)
自己去理解一下應該沒有問題，將這個公式複製到星期四和
星期五就行了。
Excel——讓排課更省心
22
依據同樣的原理就可把八、九年級的課表製作出來。我這裡
僅提供幾個公式。C25 單元格（八年級 1 班星期一第 1 節課）的
公式如下：
=HLOOKUP(C$24,排課,ROW()-23+8*INT((COLUMN()-3)/16),0)
C35 單元格（八年級 1 班星期四第 1 節課）的公式如下：
=HLOOKUP(C$34,排課,ROW()-9+8*INT((COLUMN()-3)/16),0)
C46 單元格（九年級 1 班星期一第 1 節課）的公式如下：
=HLOOKUP(C$45,排課,ROW()-44+8*INT((COLUMN()-3)/16),0)
C56 單元格（九年級 1 班星期四第 1 節課）的公式如下：
=HLOOKUP(C$55,排課,ROW()-30+8*INT((COLUMN()-3)/16),0)
這樣，年級課表也製作好了，這個是要打印來發給年級組長，
同時也送交學校領導。
23
第6章 教師課表數據
前面已經說過，當您校班級較多時，用"教師課表"一張一
張地打印來發給任課教師是比較麻煩的，因為每打印一張課表，
就要重新輸入一次教師姓名，為解決這個問題，我想到了 Word
的郵件合併功能。
6.1 主文檔的製作
新建一個 Word 文件，保存為"教師課表"，在這個文件裡，
先設計出課表的樣子，如圖 6-1
圖 6-1 Word 郵件合併主文檔
Excel——讓排課更省心
24
6.2 課程名稱
回到"教師課表數據"工作表來，這個表的第 1 列是所有任
課教師姓名（不重複），這個名單列表來自"安排"表，參考第
2 頁的第 1 章 1.2 節末尾部分，這份名單是按學科排列的；您也
可以按年級來排列，那就得分別列出七、八、九年級的任課教師
名單列表，然後再將這三個列表連接起來形成一個全校教師列表；
當然，得到教師列表後，再來按拼音排序也是可以的，就看您喜
歡了，目的是將來打印出來後按什麼順序發放比較方便，您就按
什麼順序來排列這份名單。
再來看第 1 行，它由兩部分構成，從 B 列到 AM 列列出了全
周 38 節課的標題（如週一 1 表示星期一第 1 節課„„），後面部
分 AN 列到 BY 列，也列出了全周 38 節課的班級名稱標題。最好
沒把您搞暈，也就是說，前面部分用來存放課程名稱，後面部分
用來存放是哪個班。下面來說公式，整個表比較大，公式也比較
複雜，但再複雜也不過只有兩個公式而已，剩下的工作就是複製
這兩個公式。先來看 B2 單元格里的公式：
=IFERROR(INDEX(INDIRECT("總課
表!$C"&COLUMN()+1&":$Ax"&COLUMN()+1),MATCH($A2,INDIRECT(
"總課表!$ay"&COLUMN()+1&":$ct"&COLUMN()+1),0)),"")
看出來了哈，的確很複雜。先把第 1 層外套剝離，將公式變
短，也就是去掉 IFERROR(餘下的公式,"")，因為這個部分前面已經
說過了，它的作用無非是當公式出現錯誤的時候，不將錯誤符號
第 6 章 教師課表數據
25
顯示出來（從而使該單元格顯示空白），不出錯的時候，就顯示
"餘下的公式"的內容。接著我們來看"餘下的公式"如何運作。
"餘下的公式"的主體是 index 函數，您肯定應該先搞清楚
這個函數的參數，無非就三個參數，從左至右依次是：搜索數據
的區域（或範圍）、顯示區域的第幾行、顯示區域的第幾列。在
這裡省去了行數，那就只有兩個參數了，前面部分為搜索範圍，
後面部分為列數，按這個思路去理解這個公式。這裡又多出一個
函數 INDIRECT 來，它的作用是將它括號內的參數變成"引用"。
這個公式的思路是：在"總課表"的排課區的第 1 行（"總課
表!$C3:$Ax3"）去搜索課程名稱，究竟是這一行的哪一列，由第 2
個參數決定；張 2 個參數公式的範圍與第 1 個參數的範圍有點類
似，可以參照來看。第 2 個參數的意思是在"總課表"的"任課
教師"區（即"總課表!$ay3:$ct3"）中來匹配第 1 列中的教師姓名
（如鄭霞霞），看看這個教師在"任課教師"區中的第 1 行的位
置，用這個位置數來確定第 1 個參數所確定範圍的具體位置；如
果這一行裡沒有找到第 1 列中的那個教師，那就顯示空白。
圖 6-2 "教師課表數據"的課程名稱截圖
Excel——讓排課更省心
26
下面先試圖理解第 1 部分（搜索範圍），從公式看出，該區
域內的函數為 COLUMN()，說明這個範圍只與列有關，因為不同
的列，就意味著不同的節次。這個公式在往下複製的時候，第 1
個參數不會變，但在往右複製的時候，由於 COLUMN()的值會變，
所以引用的區域就會跟著變，從而區分出不同的節次所搜索的範
圍來。
公式的第 2 部分用了 MATCH 函數，它有三個參數，分別是
匹配的值$A2，匹配的範圍 INDIRECT("總課
表!$ay"&COLUMN()+1&":$ct"&COLUMN()+1)和精確匹配（0 值），
如果理解了第 1 部分的範圍，這個範圍是一樣的，只是區域不同
而已，第 1 部分引用了排課區，第 2 部分的範圍引用了任課教師
區，如此而已。
6.3 任課班級
接下來看看 AN2 單元格的公式，它的作用是：當第 1 列第一
位教師週一第 1 節有課時，顯示是哪個班的課（即顯示班級名稱），
如果沒有課，則顯示為空，用的是 HLOOKUP 函數，前面有過介
紹，這裡略過。
第 6 章 教師課表數據
27
圖 6-3 "老師課表數據"的班級名稱截圖
因為這個表太大（寬度是 77 列：全周課程節數 38×2；高度
是 163 行：我校任課教師人數），所以截圖分成了兩部分，理解
公式時參考這兩個截圖。
6.4 郵件合併
好了，表格製作完了，將其保存好並關閉。下面該說說"郵
件合併"的事兒了。還記得本章一開頭製作的那個主文檔嗎？參
看第 23 頁圖 6-1，下面的工作就是要把剛才製作好的"郵件合併
數據"裡的內容插入到主文檔的表格中，具體方法是①：
返回到主文檔的界面，選擇"郵件"標籤，在"開始郵件合
並"欄目裡單擊"開始郵件合併"的"信函"，接著再單擊"選
擇收件人"中的"使用現有列表"，在彈出的對話框中找到"課
表"工作簿，單擊"打開"，再點"確定"，再在彈出的"選擇表
① 下面的操作均是在 Word 中進行。
Excel——讓排課更省心
28
格"對話框中點擊"教師課表數據"後點"確定"，這樣就將該
主文檔與 Excel 工作簿（課表）聯繫起來了。接下來的工作雖比
較繁瑣，卻是必須，而且沒有捷徑，硬著頭皮點吧。
先將光標放在"教師："後面，然後單擊"插入合併域"，選
擇"教師"（這樣就把 Excel 工作簿中第 1 行名稱為"教師"的那
列數據插入到此）；再將光標移至星期一第 1 節課的位置，單擊
"插入合併域"，選擇"週一 1"（這樣就把 Excel 工作簿中第 1
行名稱為"週一 1"的那列數據插入到此）；按駕車換一行，繼續
點擊"插入合併域"，選擇"M1"（這樣就把 Excel 工作簿中第 1
行名稱為"M1"的那列數據插入到此）„„依此類推，將主文檔
課程表的每一個格子填滿，插入合併域的時候需要注意：週一 1
要與 M1 對應，同樣週三 4 要與 W4 對應，否則最後製作出的課
程表會出錯。完成後看到的樣子應該與圖 6-4 相似。
圖 6-4 已經將數據插入到主文檔後的課表
第 6 章 教師課表數據
29
這一步完了，就可以看看成果了，點擊"預覽結果"，主文
檔課程表立即就變了樣，成了具體的老師和具體的班級了。您還
可以繼續點"下一條"來預覽第 2 位老師的課程，覺得基本上沒
錯了，就可以點擊"完成併合並"下的"編輯單個文檔"，再點
"確定"，現在只看見屏幕閃爍，只需一會兒功夫，162（我校教
師人數）頁的文檔就出現了，這個文檔中的每一頁，對應一位教
師的課程表，將其保存起來，隨時可以打印。這期間如果課程有
變動，即 Excel 工作簿作了調整，那麼，當您再次打開主文檔（注
意是主文檔，不是剛才保存的那份文檔！）時，會出現圖 6-5 所
示的提示：
圖 6-5 更新提示
點擊"是"按鈕（更新數據）後，新的數據就會出現在該主
文檔中，這個時候再點"完成併合並"下的"編輯單個文檔"，
再點"確定"，又產生一份新的文檔，將文檔打印出來便是更改
後的教師課表了。
特別說明：郵件合併產生的新文檔是分節的，也就是說，每
Excel——讓排課更省心
30
一頁其實是一節②，如果您不是要打印全部文檔，比如您只想打
印第 5 位教師的課表，那麼您就應該在"打印"對話框的"頁數"
那一欄輸入"s5"③而不是直接輸入 5。如果您不喜歡這樣，也有
辦法，那就是用"查找-替換"功能，將"節"的符號全部替換為
"空"，即將"節"刪除，就變成普通的頁面了④。
② 您可以從左下角的狀態欄看出。
③ 這裡的 s 就是英語"section（節）"打頭的字母。
④ 這樣，整篇文檔只有 1 節
31
第7章 班課表數據
這一章的功能與前一章相似，思路相同，不同之處是，前一
章是通過"郵件合併"功能，批量打印"教師課表"，而本章也
是通過"郵件合併"功能，批量打印"班課表"。所以本章的介
紹可能比較簡略。
7.1 課程名稱
同樣，先來說說"班課表數據"這個表格，它包含第 1 列（班
級名稱①）和第 1 行，第 1 行由兩部分構成，從 E 列到 AP 列列出
了全周 38 節課的標題，後面部分 AQ 列到 CB 列，列出了全周 38
節課的任課教師名稱標題。也就是說，前面部分用來存放課程名
稱，後面部分用來存放是哪個老師上的那節課。下面來說公式，
整個表比較大，公式卻不復雜。先來看 D2 單元格里的公式：
=HLOOKUP($A2,arrangement,17,0)
這公式簡單哦，HLOOKUP 函數的第 2 參數用了名稱而不是範
圍引用，其它沒什麼可解釋的。這一列用來將各班班主任姓名列
① 其實我校現在只有 42 個班，但我保留了幾個空白班級名稱，所以，
總共有 48 個班級名稱。
Excel——讓排課更省心
32
出，再來看 E2 單元格的公式：
=OFFSET(總課表!$C$2,COLUMN()-4,ROW()-2,)
這個公式用到一個新函數 offset，它是將"總課表"的$C$2
按"行"和"列"進行移位而得。
7.2 任課教師姓名
同樣 AQ2 單元格的公式具有類似的樣子：
=OFFSET(總課表!$AY$2,COLUMN()-42,ROW()-2,)
它是將"總課表"的$AY$2 按"行"和"列"進行移位而得。
前一公式得到課程名稱，後一公式得到該課程的任課教師，最後
複製這兩個公式即完成全表製作。
後面的"郵件合併"與前一章類似，先製作出一個主文檔，
如圖 7-1 所示。
第 7 章 班課表數據
33
圖 7-1 班級課表主文檔
然後在"郵件"標籤中，點擊"開始郵件合併"的"信函"，
接著再單擊"選擇收件人"中的"使用現有列表"，在彈出的對
話框中找到"課表"工作簿，單擊"打開"，再點"確定"，再在
彈出的"選擇表格"對話框中點擊"班課表數據"後點"確定"，
這樣就將該主文檔與 Excel 工作簿（課表）聯繫起來了。接下來
的工作 便與前一章相同，不厭其煩地點擊"插入合併域"，直至
完成，完成後的班課表應該跟圖 7-2 差不多。
Excel——讓排課更省心
34
圖 7-2 合併後的班級課表主文檔
後面的操作就不再多說了，最後完成合並，並編輯新文檔，
確定後，就得到了一個 42 頁②的新文檔，將其保存，以後可以隨
時調出並打印。
② 對應 42 個班
附 1 截圖目錄
35
附1 截圖目錄
圖 1-1 工作表列表 1
圖 1-2"安排"表 2
圖 2-1 總課表 5
圖 2-2 下拉選單輸入 6
圖 2-3 統計區部分截圖 9
圖 3-1 教師個人課表 11
圖 4-1 班級課表 17
圖 6-1 Word 郵件合併主文檔 23
圖 6-2 "教師課表數據"的課程名稱截圖 25
圖 6-3 "老師課表數據"的班級名稱截圖 27
圖 6-4 已經將數據插入到主文檔後的課表 28
圖 6-5 29
Excel——讓排課更省心
36
圖 7-1 班級課表主文檔 33
圖 7-2 合併後的班級課表主文檔 34
附 2 公式目錄
37
附2 公式目錄
=COUNTIF($R$3:$AW$17,B3) ....................................................... 3
=COUNTIF($B4:$AW$17,B3) ......................................................... 3
{=SUM(1/COUNTIF(TEACHERS,TEACHERS&""))-1} ........................ 4
=OFFSET($B$3,INT((ROW()-2)/48),MOD(ROW()-2,48)) ................. 4
=IFERROR(VLOOKUP(C3,ARRANGEMENT,COLUMN()-49,0),"")...... 7
=COUNTIF($AY3:$CT3,AY3)>1 ....................................................... 8
=COUNTIF(C$3:C$41,$B43) ........................................................... 8
=IFERROR(INDEX(總課表!$C3:$AX3,MATCH($B$2,總課
表!$AY3:$CT3,0))&CHAR(10)&HLOOKUP($B$2,總課
表!$AY3:$CT$42,44-ROW(),0),"") ....................................................... 12
=IFERROR(INDEX(總課表!$C11:$AX11,MATCH($B$2,總課
表!$AY11:$CT11,0))&CHAR(10)&HLOOKUP($B$2,總課
表!$AY11:$CT$42,36-ROW(),0),"") ..................................................... 13
=IFERROR(INDEX(總課表!$C19:$AX19,MATCH($B$2,總課
Excel——讓排課更省心
38
表!$AY19:$CT19,0))&CHAR(10)&HLOOKUP($B$2,總課
表!$AY19:$CT$42,28-ROW(),0),"") ..................................................... 14
=IFERROR(INDEX(總課表!$C27:$AX27,MATCH($B$2,總課
表!$AY27:$CT27,0))&CHAR(10)&HLOOKUP($B$2,總課
表!$AY27:$CT$42,20-ROW(),0),"") ..................................................... 14
=IFERROR(INDEX(總課表!$C35:$AX35,MATCH($B$2,總課
表!$AY35:$CT35,0))&CHAR(10)&HLOOKUP($B$2,總課
表!$AY35:$CT$42,12-ROW(),0),"") ..................................................... 14
=IFERROR(VLOOKUP($J$2,電話,2,0),"")...................................... 15
=HLOOKUP($H$1,安排!A2:$AW$19,18,0) ................................... 18
=HLOOKUP($H$1,ARRANGEMENT,17,0) ..................................... 18
=HLOOKUP($H$1,排課,ROW()-2+8*(COLUMN()-2),0)&CHAR(10)
&CHAR(10)&HLOOKUP($H$1,任課教師, ROW()-2+8*(COLUMN()-2),0)
.......................................................................................................... 18
=HLOOKUP(C$3,排課,ROW()-2+8*INT((COLUMN()-3)/16),0) ...... 21
=HLOOKUP(C$3,排課,ROW()+12+8*INT((COLUMN()-3)/16),0) ... 21
=HLOOKUP(C$24,排課,ROW()-23+8*INT((COLUMN()-3)/16),0) .. 22
附 2 公式目錄
39
=HLOOKUP(C$34,排課,ROW()-9+8*INT((COLUMN()-3)/16),0) .... 22
=HLOOKUP(C$45,排課,ROW()-44+8*INT((COLUMN()-3)/16),0) .. 22
=HLOOKUP(C$55,排課,ROW()-30+8*INT((COLUMN()-3)/16),0) .. 22
=IFERROR(INDEX(INDIRECT("總課
表!$C"&COLUMN()+1&":$AX"&COLUMN()+1),MATCH($A2,INDIRECT("
總課表!$AY"&COLUMN()+1&":$CT"&COLUMN()+1),0)),"") ............... 24
=HLOOKUP($A2,ARRANGEMENT,17,0) ....................................... 31
=OFFSET(總課表!$C$2,COLUMN()-4,ROW()-2,) .......................... 32
=OFFSET(總課表!$AY$2,COLUMN()-42,ROW()-2,) ...................... 32
附 3 Excel 常用技巧集
41
附3 Excel 常用技巧集
A. 移動及選定單元格
我們在操作 Excel 工作表的時候，經常會定位活動單元格，
或將活動單元格移動到想去的地方，以便輸入數據或公式。好像
移動單元格的操作有點太簡單而不值得說？非也。如果您掌握了
一些技巧，會大大提高您的效率。
先來說最簡單或最容易理解的方法：直接在鍵盤上移動四個
方向鍵①；或直接用鼠標點擊您想去的單元格；再就是單擊"名
稱框"（編輯欄的左側）後輸入您想去的單元格（或區域）後回
車，就可定位到您的目的單元格了②。
如果您是在已經輸入了數據的矩形區域中③，這時移動單元
① 按一次，移動一格；按住不鬆手，它會一直移動，直到你鬆手或已到
表格盡頭為止。
② 此方法也可以輸入單元格區域。
③ 要求數據區域沒有空白，也就是說，每個單元格必須要有數據，不能
為空。
Excel——讓排課更省心
42
格就太方便了，快捷鍵是：
Ctrl+方向鍵（英語輸入狀態下）
可以迅速回到數據區域的四個邊線上而不管數據區有多大。
如果在以上操作的基礎上，再配合 Shift 鍵，那麼快速移動就變成
了快速選擇④，這個組合鍵真是太神奇了，請千萬記住並熟練應
用：
Ctrl+Shift+方向鍵
強烈建議用鍵盤操作而非鼠標，包括您在操作其它應用程序
或 Windows 的時候！也許您已經找到規律了：單獨按方向鍵的時
候，移動單元格是比較慢的；如果加一個 Ctrl 鍵，速度一下就提
起來了；如果再加上 Shift 鍵，原來的移動就變成了邊移動邊選擇。
順便提一下，當您的數據區域比較大的時候，以下幾個快捷鍵肯
定是有用的：
Home：回到該行行首
Ctrl+Home：回到 A1單元格
④ 指從當前單元格一直選取到數據區的末尾，具體選取的是哪個區域，
得由您按的是方向鍵的上、下、左、右來決定。
B 複製和粘貼
43
Ctrl+end：回到數據數據區的右下角
Page up：往上翻一屏
Page down：往下翻一屏
Alt+page up：往左翻一屏
Alt+page down：往右翻一屏
B. 複製和粘貼
複製和粘貼有值得說的嗎？無論是數據，還是公式，不過就
是先單擊要複製的單元格（或區域），點擊"複製"，然後再單擊
目標單元格後點"粘貼"嗎？對的，還可以用 ctrl+C 和 Ctrl+V 快
捷鍵，再就是用鼠標操作：選擇要複製的單元格，將鼠標移到該
單元格右下角並呈現實心"+"符號時，往下拖動（或往右拖動）。
以上都是正確的方法，也經常被大家所採用。我這裡要說的
是另一種快捷鍵，當想將數據（或公式）往右邊複製時，只需選
中該單元格和右邊的目標單元格（區域）後按：
Ctrl+R：往右複製（R：right）
如果想將數據（或公式）往下複製時，只需選中該單元格和
Excel——讓排課更省心
44
下面的目標單元格（區域）後按：
Ctrl+D：往下複製（D：Down）
C. 數據錄入
數據錄入時，需要說明的是，搞清楚數據類型，尤其是貌似
是數值，但卻是文本的那一類，比如電話號碼、身份證號等，輸
入這類文本型數據時，先要將單元格格式設置成"文本"，然後
再輸入，或者在輸入時，先在英文狀態下按"'"號（該符號不會
顯示）後再輸入。如果在未設置格式的情況下，已經輸入瞭如身
份證號碼（18 位），那麼該單元格就會將該號碼的後三位顯示為
"0"⑤，此時，如果您再將該單元格格式設置為"文本"，excel
也無回天之力，解決的辦法只有重新輸入。默認情況下可以通過
單元格的對齊方式來識別數據類型：數值左對齊，文本右對齊。
另外，除了在"選項→高級"的"按 Enter 鍵後移動所選內
容"的"方向"裡選擇向下或向右，滿足您自己的喜好外，要想
提高輸入速度，還可以採用以下辦法：先選定輸入範圍，然後再
輸入，每輸完一個單元格按一次"Tab"鍵。
⑤ 這是因為該單元格將其識別為數值了，而每個單元格最多隻能存儲
15 位數據，多出的部分以 0 代替。
D 數據排序
45
有效性設置也可幫助您在輸入時出錯，如：限定學生成績的
輸入範圍為 0-100 分，可在"數據有效性"設置中，將允許值設
為整數，輸入最大值和最小值後"確定"，這樣，當您輸入的數
值不在這個範圍中的時候，excel 就會停止並提醒您。又如：您需
要在一列中輸入身份證號碼，要求不重複（重複時提醒），輸入
前同樣"數據有效性"中設置，選"自定義"，然後在"公式"
中輸入：
=countif($a$1:$a$100,a1)=1
如果已經輸入了數據，要檢查有沒有重複值（有的話用顏色
標識出來），此時可選定該數據區域，然後在"條件格式"的"僅
對唯一值或重複值設置格式"中進行設置。
D. 數據排序
數值的排序，無非就是升序或者降序，很簡單，但有一點很
重要，那就是不能有合併單元格。文本的排序同樣可以是升序或
者降序，同時還可以用"自定義序列"來排序，這就給我們提供
了很大的方便。比如，我想按：一等獎、二等獎、三等獎的順序
來排，默認情況下是按第一個字拼音的首字母在 26 個字母中的
順序來排序，這顯示不符合我的想法，那就只能定義一個新序列，
然後按新定義的這個新序列來排序才能得到想要的結果。類似的
還有，將本單位的名單按您想要的順序來排等，方法都相同。
Excel——讓排課更省心
46
E. 表格打印
一般情況下，往 excel 裡輸入數據是有要求的：第 1 行為字
段行，以後各行為數據，並且中間的數據不要有空白，也不要有
合併單元格，這樣，您在排序以及以後的其它操作中才不會出錯。
但是這樣一來，當您在打印這個表格時，會出現無抬頭的現
象，我的解決辦法是用頁眉來當抬頭，但在表格中看不直觀，只
有在打印預覽中才可見。不管它，設置好標題行重複，直接打印
即可。有時，可能只需要打印表格的部分內容：既可以選定這部
分內容後打印（選擇打印選定區域），也可以將這部分內容選定
後，在"頁面佈局"中設置打印區域，然後再打印就沒問題了。
最後的說明：這個 Word 文檔，設計成 A4 紙，全部打印好後，
在中縫訂上釘子同，從中間對摺後便成為一本小冊子，攜帶方便。
其頁面佈局，可從"頁面設置"對話框裡查看。樣式的定義可從
"開始"選項卡→樣式組中查看。
閱讀更多 科普分享 的文章
