字典二級下拉菜單的製作

大家好，今日我們繼續講解VBA數組與字典解決方案，今日講解第51講：對字典嵌套的理解及二級下拉菜單的製作.

在講字典的時候,我反覆說明,字典看視非常簡單,由於它具有直達性可以省略去我們大量的循環查找代碼,所以使用起來要特別留意很多用法和常規思路是不一致的,對於字典的理解：

1：鍵key、鍵值（或者較項）item 是非常重要的，key 一定是字符串，具有唯一性，item 可以為任何類型的數據.

2：keys 和items 是一維數組，他們的開始是從0開始到count-1結束。

3：再次理解字典的直達性，對於給定的鍵，可以直接得出鍵值不必循環查找.

今日我們利用字典的嵌套完成一個兩級下拉菜單的製作，大家要認真理解，如下面的數據：

我要在一級菜單中實現A列的數值，在二級下拉菜單中實現對應於A列的B列的值，下面看我給出的代碼：

Private Sub ComboBox1_Change()

ComboBox2.Clear

'二級下拉框對應的是第一級字典的鍵值為鍵的字典

ComboBox2.List = mydic(ComboBox1.Value).keys

End Sub

Private Sub UserForm_Activate() '第51講 字典的嵌套的理解及二級下拉菜單的製作

'將數據裝入數組

myarr = Range("a1").CurrentRegion.Value

Set mydic = CreateObject("Scripting.Dictionary")

For i = 2 To UBound(myarr)

strF = myarr(i, 1)

strS = myarr(i, 2)

If Not mydic.Exists(strF) Then

'建立嵌套字典，第一重字典的鍵對應的鍵值為字典

Set mydicTemp = CreateObject("Scripting.Dictionary")

'注意下面的兩種寫法

'Set mydic.Item(strF) = mydicTemp

Set mydic(strF) = mydicTemp

End If

'注意下面的兩種寫法，嵌套字典的字典的鍵記入，鍵值為空

'mydic.Item(strF).Item(strS) = ""

mydic(strF)(strS) = ""

Next i

'一級下拉框對應的是第一級字典的鍵

ComboBox1.List = mydic.keys

End Sub

代碼截圖：

代碼講解：

1 上述代碼利用了字典的嵌套，解決了兩級下拉菜單的製作問題，在利用前要先加上一個窗體：

2 '將數據裝入數組

myarr = Range("a1").CurrentRegion.Value

上述代碼將源數據寫入數組中備用

3 Set mydic = CreateObject("Scripting.Dictionary")

上述代碼定義外層的字典.

4 For i = 2 To UBound(myarr)

strF = myarr(i, 1)

strS = myarr(i, 2)

If Not mydic.Exists(strF) Then

'建立嵌套字典，第一重字典的鍵對應的鍵值為字典

Set mydicTemp = CreateObject("Scripting.Dictionary")

'注意下面的兩種寫法

'Set mydic.Item(strF) = mydicTemp

Set mydic(strF) = mydicTemp

End If

'注意下面的兩種寫法，嵌套字典的字典的鍵記入，鍵值為空

'mydic.Item(strF).Item(strS) = ""

mydic(strF)(strS) = ""

Next i

上述代碼中利用FOR NEXT在數組中建立循環,當Not mydic.Exists(strF),將數據存入字典,鍵是strF ,鍵值是一個字典:mydicTemp,如果能夠找到外層字典的鍵,那麼將建立內層字典的,即: mydic(strF)(strS) = "",此處大家要好好理解一下.

5 '一級下拉框對應的是第一級字典的鍵

ComboBox1.List = mydic.keys

上述代碼實現的是在ComboBox1中建立一級下拉菜單,是外層字典的鍵

6 ComboBox2.Clear

'二級下拉框對應的是第一級字典的鍵值為鍵的字典

ComboBox2.List = mydic(ComboBox1.Value).keys

上述代碼實現的是在ComboBox2中建立二級下拉菜單,是內層字典的鍵

下面看看代碼的運行:

今日內容迴向:

1 如何利用字典實現控件的下拉菜單?

2 對於字典的嵌套是否理解呢?

3 對於字典的特點是否掌握了?