大家好，今日我們繼續講解VBA數組與字典解決方案，今日的內容是第58講，利用工作表函數，對字典的鍵進行排序,並給出對應的重複個數。
對於排序，大家並不陌生，在之前的講解中，我也講了利用sort進行排序的方法。今日我們講解利用工作表函數對數值排序.對於工作函數，我這講利用了LARGE,還可以使用SMALL.都是可以的，這類函數在實際的應用中也十分方便。
實例，我們看下面的數據，在A列中有若干多的數據，我們要對這些數值進行排序，並將重複的次數記錄。
思路分析：我們要先將數據放到字典中，放的同時利用鍵值進行累計出現重複的次數，然後取出鍵和鍵值放到對應的數組中，同時再建立一個數組用於存放排序的結果，然後在數組中提取數值，提取的時候是按照從大到小順序進行。並將結果放到數組中，最後回填數據。下面看我給出的代碼：
Sub mynzsz_58() '第58講 利用工作表函數，對字典的鍵進行排序,並給出對應的重複個數
Dim ran
Sheets("58").Select
Set mydic = CreateObject("Scripting.Dictionary") '字典
'將數據放入字典中，並計數
For Each ran In Sheets("58").Range("a2:a" & Range("a2").End(xlDown).Row)
If ran.Value <> "" Then
If Not mydic.exists(ran.Value) Then
mydic.Add ran.Value, 1 '初始值為1
Else
mydic(ran.Value) = mydic(ran.Value) + 1 '重複時累加
End If
End If
Next
'將字典的鍵和鍵值，取出，放到數組中
k = mydic.keys: T = mydic.items
'新建一個數組，用於放排序的結果
ReDim X(1 To mydic.Count, 1 To 2)
For i = 1 To mydic.Count
X(i, 1) = Application.Large(k, i) '按最大值的先後將數據放到數組中
X(i, 2) = mydic(X(i, 1)) '提取相應的鍵值
Next
[e:f].Clear
[e1] = "排序": [f1] = "重複次數"
Sheets("58").[e2].Resize(mydic.Count, 2) = X
Set mydic = Nothing
End Sub
代碼截圖：
代碼講解：
1 上述代碼實現將數據放到字典mydic中，放的同時利用鍵值進行累計出現重複的次數，然後取出鍵和鍵值放到對應的數組k,t中備用，同時再建立一個數組x用於存放排序的結果，然後在數組k中提取數值，提取是按照從大到小的順序進行。並將結果放到數組x中，最後回填數據。
2 For Each ran In Sheets("58").Range("a2:a" & Range("a2").End(xlDown).Row)
If ran.Value <> "" Then
If Not mydic.exists(ran.Value) Then
mydic.Add ran.Value, 1 '初始值為1
Else
mydic(ran.Value) = mydic(ran.Value) + 1 '重複時累加
End If
End If
Next
上述代碼在將數據放到字典中，注意這裡有一個是否重複的判定：Not mydic.exists(ran.Value)
3 '將字典的鍵和鍵值，取出，放到數組中
k = mydic.keys: T = mydic.items
此處要注意的是k 和 t 的含義，是一個一維數組，之後的代碼要在k中建立一個循環提取數值。
4 For i = 1 To mydic.Count
X(i, 1) = Application.Large(k, i) '按最大值的先後將數據放到數組中
X(i, 2) = mydic(X(i, 1)) '提取相應的鍵值
Next
上述代碼按照i值在k中提取數據，i是從小到大排序的，所以LARGE函數會相應出現從大到小的排序，Application.Large(k, i)，要注意這個工作表函數的用法. 將mydic(X(i, 1)) 提取相應的鍵值放到X(i, 2)中
5 Sheets("58").[e2].Resize(mydic.Count, 2) = X
上述代碼回填數據
下面看代碼的運行：
今日內容迴向：
1 如何實現鍵的排序？
2 利用上述工作表函數如何實現從小到大的排序？
閱讀更多 VBA專家 的文章
